Originally posted by PE&OAS@Mar 11 2006, 01:15 PM
eheh... abi ben acemi halimle şunu soruyorum ki, o adreslere elimizdeki müziği nasıl koyacaz? hafızaya müziği load "hede"8 diye yükleyip sonra datalarımı yazacaz? resim dosyasını nasıl belirtcez, disketin şurasında burada oku mu diyecez? anlatabildim mi??? :unsure:

[post=5877]Quoted post[/post]

Müzik hangi adresler arasındaysa ordan kullanman lazım, müziği kolay kolay taşıyamazsın. Çünkü müzik yalnızca veriden ibaret değil, playerı da içinde geliyor ve örnek olarak;
jmp $107e
gibi bir satır içeriyor. Sen bunu başka bir adrese taşısan da o hep aynı adresler üzerinden işlem yapmak isteyecektir. Müziği taşıman için relocate etmen gerekir. Bunu yapabilmen için de müziğin hangi trackerla yapıldığını bilmen gerekir. Eğer müziği siz yaptıysanız ya da trackerla açabiliyorsanız, bu durumda birçok tracker farklı adreslere müziği kaydedebilir.
Grafikte ise böyle bir sorunun olmayacaktır.
şimdi gelelim nasıl yükleteceğine. Evet aynen;
load"muzik ismi",8,1
şeklinde yükletebilirsin müziği hafızaya. Dikkat etmen gereken şey elbetteki müziğin, grafiğin, kodun ve diğer dataların hafıza adreslerinin çakışmamasıdır. Örnek olarak sen kodunu $080d'den yazmaya başladın ve kodun çok uzadı $1000'i geçti. Bu durumda müziği kodun üstüne yükletmiş olursun ki elbetteki işin sonu bir yerden sonra programın çalışmamasıdır. Bunlara dikkat ettiğin sürece tüm dataları teker teker yükleyip, kodu da yükleyip (ya da Turbo Assembler hafızadaysa derleyip) çalıştırabilirsin. En son olarak da tüm bu parçaları Sladge Hammer programıyla sıkıştırılmış tek bir paket haline getirebilirsin.
Ancak o kadar boşuna çapraz geliştirme semineri vermedik herhalde. Eğer PC'de ACME kullanacak olursan C'deki #include deleyici komutuna benzer bir şekilde;
!source
!binary
gibi komutlar ile projenin tüm datalarını tek bir seferde bir araya toplaman mümkün.
Ben buraya böyle siz sordukça dağınık dağınık yazıyorum ama kafanız karışıyorsa isterseniz soru sormayı bırakın, Nightlord'a konu başlıklarını iletin, o size düzenli bir tutorial oluşturur bu konularda. Çünkü benim başka tutorial projelerim var şu anda.

aslinda bu sorular iyi oluyor. beni de yonlendiriyor. arti skate bence senin cevaplarin da cok iyi oluyor(sen daginik olduklarini dusunsen de 🙂 ). ben her zaman tek kisinin yazdiklarindan bazi seyleri ogrenemeyerek gecerim. hep en az ikinci birisinin de yazdiklari ile tamamlanir kafamda konular. o yuzden sen vakit buldukca sorulara cevap yazmaya devam et bence...
skate hades ve nightlord dokumanlari ucgeninden bayagi bir turkce kaynak olusturduk sayilir c64 icin 🙂 ve devam edecegiz

nightlord dökümanlarını sabırsızlıkla bekliyorum abi. ayrıca herkese verdikleri cevaplar için teşekkürler... bir soru daha patlatacağım: hvsc vs.'den indirdiğimiz .sid uzantılı dosyaların playerları içinde değil gibi geldi bana doğru mu?

Butun muziklerin Player'lari icindedir.

Originally posted by PE&OAS@Mar 12 2006, 07:28 PM
nightlord dökümanlarını sabırsızlıkla bekliyorum abi. ayrıca herkese verdikleri cevaplar için teşekkürler... bir soru daha patlatacağım: hvsc vs.'den indirdiğimiz .sid uzantılı dosyaların playerları içinde değil gibi geldi bana doğru mu?

[post=5937]Quoted post[/post]

Hydrogen doğru söylüyor, playerları içinde ve .sid uzantılı müziklerin normal müziklerden tek farkı başında belli bir headerı olmasıdır. Bu müzikleri .prg'ye çevirmek istersen, öncelikle müziğin başlangıç adresine bak ve daha sınra .sid dosyasını açıp bu başlangıç adresinin olduğu yeri ara. O bölüme kadar olan kısmı silersen .prg dosyasını elde etmiş olursun. Birçok müzik;
jmp $xxxx
jmp $xxxx
şeklinde başlar. Bu da hafızada
4c xx xx 4c xx xx
şeklinde gözükür. Sen örnek olarak $1000'den başlayan bir müziği prg olarak kaydettiğinde $1000 adresi low-byte high-byte sırasını değiştirerek;
00 10
şeklinde iki bytelık bir header ekler dosyanın başına. Kısacası $1000'den başlayan bir müziği .sid içersinden araklamak istersen .prg olarak;
00 10 4c xx xx 4c xx xx
şeklinde bir bölüm araman lazım dosyanın başlarında. Bu bölümü gördüğün zaman, buraya kadar olan bölümü silip kaydedecek olursan müziği .prg'ye çevirmiş olursun. Bunu yapan hazır utilityler de var ama bence gerek yok. Hex Editor gayet yeterli bu iş için.
http://www.chmaas.handshake.de/delphi/free...xvi32/xvi32.htm
Ekteki resimde baştan silmen gereken bölüm kırmızıyla işaretlenmiştir.

hocam bu sid'i çaldıramadım. bu örnek üzerinden yardım edebilirimisin.

[SIZE=1][COLOR=#008000]
!to[/COLOR][/SIZE][SIZE=1][COLOR=#000040] [/COLOR][/SIZE][SIZE=1][COLOR=#800080]"sidplay.prg"[/COLOR][/SIZE][SIZE=1][COLOR=#000040],cbm
[/COLOR][/SIZE][SIZE=1][COLOR=#008000]*=[/COLOR][/SIZE][SIZE=1][COLOR=#000040] [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$0800
[/COLOR][/SIZE][SIZE=1][COLOR=#008000]!byte[/COLOR][/SIZE][SIZE=1][COLOR=#000040] [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$00[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$0c[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$08[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$0a[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$00[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$9e[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$32[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$31[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$31[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$32[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$00[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$00[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$00[/COLOR][/SIZE][SIZE=1][COLOR=#000040],[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$00
[/COLOR][/SIZE][SIZE=1][COLOR=#000040] 
 
[/COLOR][/SIZE][SIZE=1][COLOR=#008000]*=[/COLOR][/SIZE][SIZE=1][COLOR=#000040] [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$1000
[/COLOR][/SIZE][SIZE=1][COLOR=#000040][/COLOR][/SIZE][SIZE=1][COLOR=#008000]!bin[/COLOR][/SIZE][SIZE=1][COLOR=#000040] [/COLOR][/SIZE][SIZE=1][COLOR=#800080]"/sample/musicandplayer/allegretto_mus.sid"
[/COLOR][/SIZE][SIZE=1][COLOR=#000040][/COLOR][/SIZE][SIZE=1][COLOR=#008000]*=[/COLOR][/SIZE][SIZE=1][COLOR=#000040] [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$0840
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]start:
lda [/COLOR][/SIZE][SIZE=1][COLOR=#008080]#[/COLOR][/SIZE][SIZE=1][COLOR=#804000]$[/COLOR][/SIZE][SIZE=1][COLOR=#000040]0
sta [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$d020
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]jsr [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$1000
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]
play:
lda [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$d012
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]cmp [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$FF
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]bne play
p_01: lda [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$d012
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]cmp [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$10
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]bne p_01
p_02: lda [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$d012
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]cmp [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$FF
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]bne p_02
jsr [/COLOR][/SIZE][SIZE=1][COLOR=#804000]$1003
[/COLOR][/SIZE][SIZE=1][COLOR=#000040]jmp play
[/COLOR][/SIZE]

@esmaeild
ilk gözüme çarpan hata CMP komutlarının parametreleri sabit bir sayı değilde başka bir adresin içeriğini alması. Bu nedenle müziğin çalmayabilir. CMP $.. değild CMP #$.. olmalı.

bu hali hazırda çalmakta olan bir sistemdi ekteki ile birlikte çalıyor. ilk defa sid çaldırmayı deniyorumda acemiyim bu konuda.

Aslında bu çok hoş olmayan bir metod ama ilk olarak bunu göndereyim.

!to "player.prg",cbm
 *= $c000
 sei
 lda #0    ; 0 nolu parçayı seç
 jsr $1000 ; Müziği başlangıç durumuna getir
baslangic:
 lda #$80  ;
beklet: cmp $d012 ; Bir tarama beklet 
 bne beklet;
 jsr $1003 ; Müziği çaldır
 jmp baslangic ; Döngüye gir
 *= $1000
 !binary "music.bin"

sys 49152
ile çalıştırabilirsiniz.

Bu da olması gereken (interruptlı)

!to "player.prg",cbm
 *= $c000
 sei
 lda #$7f
 sta $dc0d
 lda #$00
 sta $dc0e
 lda #$01
 sta $d01a
 lda #$00  ; 0 nolu parçayı seç
 jsr $1000 ; Müziği başlangıç durumuna getir
 lda #$1b
 sta $d011
 lda #$50
 sta $d012
 lda #<int
 sta $0314
 lda #>int
 sta $0315
 cli
 rts
int
 inc $d020
 jsr $1003 ; Müziği çaldır

 dec $d020
 inc $d019
 jmp $ea31
 *= $1000
 !binary "music.bin"

inc $d020 ve dec $d020 satırları aslında gereksiz. Bu satırlar müziğin çalma rutininden önce çerçeve rengini bir arttırıp, rutinden döndükten sonra bir azaltarak toplamda ne kadar zaman yediğini göstermek için kullanılıyor. Gerisi zaten bildiğiniz interrupt rutini.

Aklıma gelmişken "0 nolu parçayı seç" dediğim jsr $1000'den önceki satır ne işe yarar diye merak edenler olabilir. SID müzikleri genel olarak (editörüne göre değişiklik gösterebilir) tek bir parça halinde değil de parçalardan (yani tracklerden) oluşan müzikler halinde tasarlanmıştır. Yine editörden editöre değişebildiği halde genel olarak DMC, JCH, Goat Tracker gibi eskisinden yenisine birçok editörün standart kabul ettiği biçimiyle accumulator değerine göre parçalar hazırlanır ve çalınır. Yani 0'dan 3'e 4 farklı track olan bir müzikte
lda #trackno
jsr $1000
diyerek o tracki seçeriz. 1 numaralı track'i çalacaksak
lda #1
jsr $1000
dememiz gerekiyor. ilk track 0 numaralı tracktir. daha sonra
jsr $1003 dedikçe o parça çalmaya başlar. Genellikle tek track olarak kullandığımız için SIDleri jsr $1000'den önce lda #0 deriz.
Birden fazla track en çok nerde kullanılır? Genellikle oyunlarda. Oyunların menü müziği, yükleme ekranı müziği, oyun sırasında çalan müzik, game over müziği ve hatta bazı oyunlarda ses efektleri farklı trackler halinde tek bir SID dosyası içersinde yer alabilir.

music.bin i çalıyor zaten sid i çalmıyor. yukarıda ek te gönderdim.

Pardon, görmemişim.
Bu SID'in formatı biraz garip. Standarda pek uymuyor. SID Player çalabildiği halde infosunu gösterirken biraz saçmalıyor. Başka bir SID deneyecek olursan işin daha kolay olur. Unutmaman gereken SID'in başındaki header kısımlarını geçmen gerektiği. Örneğin SID'in başında 126 bytelık bir header varsa;
!binary "music.sid", ,126
şeklinde yükletmen lazım. Ben nerden bilicem kaç byte atlamam gerektiğini dersen bir Hex Editor ile açıp bakarsan dosyaya (ben XVI32 kullanıyorum) 100küsürüncü bytedan itibaren 3 byte arayla iki adet "4C" görmen lazım. Bu sidlerin genelde başladığı
JMP $xxxx
JMP $xxxx
formatındaki JMP komutuna karşılık geliyor. Örnek SID datası ve başlangıcı...
50 53 49 44 00 02 00 7C 00 00 10 00 10 03 00 01 00 01 00 00 00 00 53 70 75 6E 6B 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 54 68 6F 6D 61 73 20 4D 6F 67 65 6E 73 65 6E 20 28 44 52 41 58 29 00 00 00 00 00 00 00 00 00 00 32 30 30 36 20 4D 61 6E 69 61 63 73 20 6F 66 20 4E 6F 69 73 65 00 00 00 00 00 00 00 00 00 00 00 00 14 00 00 00 00 00 10 4C 40 10 4C C6 10 01 02 04 0F F1 07 7B 6F 70 05 10 10 FC 3E 18 2B 2B 08 08 08 FE FE FE 00 E0 08 2D 50 4C 41 59 45 52 20 42 59 20 4C 41 58 49 54 59 2E 4D 55 53 49 43 20 42 59 20 44......
Burada kırmızıyla işaretli kısım SID dosyasının içindeki binary haldeki commodore 64'ün okuyabileceği formattaki SID verilerine tekabül ediyor. Mavi bytelar yükleme adresi (bu örnekte $1000) ve baştaki siyah bölüm ise PC'deki playerların kullandığı alan (c64'de de PC'deki SID dosyalarını çalan bir proje beta olarak devam ediyor).
ıster bu bölümü dediğim gibi dosyayı ilerden yükleterek geçersin, istersen de baş kısmını uçurup SID'i binary dosyaya çevirip öyle kullanırsın. Ben genellikle ikincisini tercih ediyorum.
Not: SID'i otomatik olarak PRG'ye çeviren hazır programlar da mevcut.

bende bayağı bir sid dosyası var. arnold64 ftp sitesinden indirmiştim. bunların içinden 4-5 tanesine baktım olmadı. 4c xx 4c ler bunlarda yok 🙂 bu 4c lilerin yoğunlukta olduğu bir yer varmı indirebileceğim. sizin bulduğunuz yerden indireyim bende.yada aslında bunlar niye çalmıyor diye bakmak lazım olaya. çünkü benim gibi ilk denemelerde çakılıp kalan bir çok kişi sid uzantılı dosyalardan faydalanamayacak. ben dün intro denemelerimin arkasına music.bin i koydum. çaldırıyordum ne güzel dedim ki kendime başka müzikler de deneyim bakayım nasıl oluyor. ilk sid te gümledim. şimdi aslında bu sid dosyasının içini baştan sona inceleyip neden çalmadığını bulup çaldırma durumum var. ama şu anda benim sid in ayrıntılarına dalmamam gerekiyor. ona ayrıca geniş bir zaman ayırıcam. sadece öğrendiğim rasterlar ile yaptığım denemelerde arkada değişik birşeyler çalsın istiyorum. sidplayerdan dinleyip beğendiğimi monte etmek istiyorum.

HSVC Sid Collection'da 90 sonrası yapılmış birçok müzik bahsettiğim formata uygundur. Tüm collectionı indirmek zorunda değilsin.
www.c64.org
Bu adresten bas en üstteki Sid Find linkine. Ordan arama yaparak istediğin sidi bulup indirebilirsin.
Bu arada bir yanlış anlaşılma olmasın. SID dediğin dosya tipi PC'ye özeldir. Normalde Commodore 64'de zaten her zaman music.bin dosyasının formatında kullanacaksın müzikleri.
Niye bazı SIDler farklı? Çünkü bu işin bir standardı yok. Bazı müziklerin playerları komple içinde gelir mesela. Yani sen başlangıç adresine jumplarsın, o interruptını açar ve çalmaya başlar. Sen hiçbirşeyle uğraşmazsın. Bazılarını ise çaldırmak daha zordur. Ama bu işte standart kabul edilebilecek format şu. Müziğin başlangıç adresinde bir JMP var. Ve o müziği başlangıç konumuna getiren yere gidiyor. Sen o adrese (örneğin $1000) JSR'leyerek gerekli işlemleri yapıp programına geri dönüyorsun. Daha sonra her taramada bir kez müziğim başlangıcından itibaren 3 byte ilerde kalan JMP'ın olduğu adresi (bu örnekte $1003) çağırarak müziğini çaldırıyorsun.
Diğer müzikleri çaldırmak niye zor? Dediğim gibi bir kısmı kendi interruptlarını falan açıyorlar. Bu da senin interruptlarınla çakışabilir. Bu durumda senin yapman gereken müziğin playerını inceleyip yine bu $1000 ve $1003 benzeri adreslerini öğrenip bu adresleri müziğin içinde gelen playerı kullanmadan kendi koduna uyarlamaktır.
Dediğim gibi bu basit bir iş değil. Tüm SIDleri çalabilmek için PSID64 isimli bir sourceforge.net projesi var. ıstersen onu inceleyebilirsin.
http://psid64.sourceforge.net/
Normal koşullarda sen kendi demona/introna/oyununa müzik yapılmasını istediğin zaman müzisyen standard bir player kullandığı taktirde problem yaşamazsın. Senin incelediğin müziklerin büyük çoğunluğu 80'lerden kalma eski format sidlerdir.